.SUBCKT NCV97200_BOOST VIN2 DC GND VINJ2 VOUT2 PARAM: L1 = 4.7u 
R_up2         VINJ2 VFBE2  42k
R_low2         VFBE2 GND  8k 
R_FB 	 	VFBE2 VFBI2 5k
E_E2         GND LIMIT V2 VFBI2 44500
V_V2         V2 GND 0.8
R_esd 		LIMIT GND 1MEG
R_8 		LIMIT COMP2 1m
E_LIMIT1     LIMIT LIMIT2 VALUE {LIMIT(V(LIMIT),0.250,2.5)}
R_lim			LIMIT2 COMP2 1m
Ccomp1 		COMP2 SUBCOMP2 265pf
Rcomp1		SUBCOMP2 VFBI2 63.3k 
Ccomp2		COMP2 VFBI2 10.6p
V_dum		CTRL2 COMP2 0
X_U2         GND VIN2 VOUT2 CTRL2 DC HS LS PWMCM_L PARAM: L={L1} FS=2300000 RI=-0.61 SE=630000
.model MBR1520	D(Is=4.091u Rs=4.683m Ikf=3.519 N=1 Xti=0 Eg=1.11 Cjo=2.216n
+		M=.4608 Vj=.75 Fc=.5 Isr=865.4u Nr=2)
D_LS         0 LS MBR1520
Rdson	    HS GND 500m

.ENDS

.SUBCKT PWMCM_L a c p vc dc SW DIO param: L=4.7u Fs=200k Ri=1 Se=100m 
*
* This subckt is a current-mode DCM-CCM model including saturation voltages
*
Edc dcx 0 value = { v(d2)*v(cx,p)/(v(a,p)-v(cx,p)+1u) }
Xdc dcx dc limit param: clampH=0.99 clampL=7m
Ed2 d2X 0 value = { (2*{L}*{Fs}*I(VM)/(V(dc)*V(a,cx)+1u)) - V(dc) }
Xd2 d2X dc d2 limit2
GIap a p value = { (V(dc)/(V(dc)+V(d2)+1u))*I(VM) }
GIpc p cx value = { V(vc)/{Ri} }
GImju cx p value = { {Se}*V(dc)/({Ri}*{Fs}) + (v(cx,p)/{L})*V(d2)*{1/Fs}*(1-(V(dc)+V(d2))/2) }
Rdum1 dc 0 1Meg
Rdum2 vc 0 1Meg
Eloss cx cxx Value = { V(SW)*V(dc)+V(DIO)*V(d2) }
VM cxx c 
XC1 cxx p mode varicap
Emode mode 0 Value = { VALIF((2*{L}*{Fs}*I(VM)/(V(dc)*V(a,cx)+1u))
+ < 1, 1p , {4/((L)*(6.28*Fs)^2)}	) }
*
**** Loss generator ****
GSW 0 SW value = { I(VM) }
GID 0 DIO value = { I(VM) }
.ENDS


********
	.subckt limit d dc PARAM: clampH=0.88 clampL=16m
	Gd 0 dcx VALUE = { V(d)*100u }
	Rdc dcx 0 10k
	V1 clpn 0 {clampL}
	V2 clpp 0 {clampH}
	D1 clpn dcx dclamp
	D2 dcx clpp dclamp
	Edc dc 0 value={ V(dcx) }
	.model dclamp D Level=2  n=0.01 rs=100m
	.ENDS limit

	.subckt limit2 d2nc d d2c
	*
	Gd 0 d2cx d2nc 0 100u
	Rdc d2cx 0 10k
	V1 clpn 0 7m
	E2 clpp 0 Value = { 1-V(d)-6.687m }
	D1 clpn d2cx dclamp
	D2 d2cx clpp dclamp
	Edc d2c 0 value={ V(d2cx) }
	.model dclamp D Level=2  n=0.01 rs=100m
	.ENDS limit2

	.SUBCKT VARICAP 1 2 CTRL
	R1 1 3 1u
	VC 3 4
	EBC 4 2 Value = { (1/v(ctrl))*v(int) }
	GINT 0 INT Value = { I(VC) }
	CINT INT 0 1
	Rdum INT 0 10E10
	.ENDS 
*
********